plugins {
	java
	id("org.springframework.boot") version "3.5.0"
	id("io.spring.dependency-management") version "1.1.7"
	id("com.diffplug.spotless") version "7.0.4"
}

group = "io.github.markl4yg.hca"
version = "0.0.1-SNAPSHOT"
val springDebugLogging = providers.gradleProperty("SPRING_DEBUG").orNull == "true"

apply(
	from = file("./gradle/spotless.gradle")
)

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

configurations {
	compileOnly {
		extendsFrom(configurations.annotationProcessor.get())
	}
}

repositories {
	mavenCentral()
}

dependencies {
    implementation("org.zeroturnaround:zt-exec:1.12")
	implementation("org.apache.commons:commons-lang3:3.17.0")
	implementation("org.springframework.boot:spring-boot-autoconfigure")

    implementation("org.springframework.boot:spring-boot-starter-jdbc")
    implementation("org.xerial:sqlite-jdbc")
    implementation("org.springframework.boot:spring-boot-starter-data-jpa")
    implementation("org.springframework.boot:spring-boot-starter-validation")
    implementation("org.hibernate.orm:hibernate-community-dialects")

	implementation("org.springframework.boot:spring-boot-starter-security")
	implementation("org.springframework.boot:spring-boot-starter-web")
	implementation("org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.9")

	implementation("org.flywaydb:flyway-core")

	compileOnly("org.projectlombok:lombok")
	annotationProcessor("org.projectlombok:lombok")

	testImplementation("org.springframework.boot:spring-boot-starter-test")
	testImplementation("org.springframework.security:spring-security-test")
	testImplementation("org.assertj:assertj-core")
	testImplementation("org.mockito:mockito-core")

	testRuntimeOnly("org.junit.platform:junit-platform-launcher")
}

tasks.withType<Test> {
    useJUnitPlatform()
	if (springDebugLogging) {
		// Additional Hibernate logging
		jvmArgs("-Dlogging.level.org.sqlite=DEBUG")
		jvmArgs("-Dlogging.level.org.hibernate=DEBUG")
		jvmArgs("-Dhibernate.show_sql=true")
		jvmArgs("-Dhibernate.format_sql=true")
	}

    systemProperty("spring.profiles.active", "test")
	jvmArgs("-XX:+EnableDynamicAgentLoading") // DynamicAgentLoading for byteBuddy within Mockito
	testLogging.showStandardStreams = true
}